liefdesbrieven

apply plugin: 'com.android.application'

// Upload-keystore voor Play. Staat buiten git (android/keystore.properties; de keystore
// en de wachtwoorden liggen in de eigen secrets-opslag). Ontbreekt het bestand, dan compileert een
// release-build nog steeds — hij is alleen niet ondertekend en dus niet te uploaden.
def keystorePropsFile = rootProject.file('keystore.properties')
def keystoreProps = new Properties()
if (keystorePropsFile.exists()) {
    keystorePropsFile.withInputStream { keystoreProps.load(it) }
}

android {
    namespace = "nl.bramluiken.liefdesbrieven"
    compileSdk = rootProject.ext.compileSdkVersion
    defaultConfig {
        applicationId "nl.bramluiken.liefdesbrieven"
        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.targetSdkVersion
        versionCode 6
        versionName "1.0.1"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        aaptOptions {
             // Files and dirs to omit from the packaged assets dir, modified to accommodate modern web apps.
             // Default: https://android.googlesource.com/platform/frameworks/base/+/282e181b58cf72b6ca770dc7ca5f91f135444502/tools/aapt/AaptAssets.cpp#61
            ignoreAssetsPattern = '!.svn:!.git:!.ds_store:!*.scc:.*:!CVS:!thumbs.db:!picasa.ini:!*~'
        }
    }
    signingConfigs {
        release {
            if (keystoreProps.containsKey('storeFile')) {
                storeFile file(keystoreProps['storeFile'])
                storePassword keystoreProps['storePassword']
                keyAlias keystoreProps['keyAlias']
                keyPassword keystoreProps['keyPassword']
            }
        }
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            if (keystoreProps.containsKey('storeFile')) {
                signingConfig signingConfigs.release
            }
        }
    }
}

repositories {
    flatDir{
        dirs '../capacitor-cordova-android-plugins/src/main/libs', 'libs'
    }
}

dependencies {
    implementation fileTree(include: ['*.jar'], dir: 'libs')
    implementation "androidx.appcompat:appcompat:$androidxAppCompatVersion"
    implementation "androidx.coordinatorlayout:coordinatorlayout:$androidxCoordinatorLayoutVersion"
    implementation "androidx.core:core-splashscreen:$coreSplashScreenVersion"
    // Bericht als er post ligt: één ingepland moment per dag, blijft staan over een herstart heen
    implementation "androidx.work:work-runtime:$androidxWorkVersion"
    /*
     * WorkManager's Worker heeft ListenableFuture nodig om te compileren. Bij het draaien zit die
     * klasse er al in (guava komt mee met de Play Billing-plugin), maar op het compileerpad wint
     * het lége artefact dat guava daarvoor publiceert — 9999.0-empty-to-avoid-conflict-with-guava,
     * en 9999.0 is nu eenmaal hoger dan 1.0 — en dan valt er niets tegenaan te compileren. Die
     * versiekeuze is niet te overrulen: AGP trekt het compileerpad gelijk met het runtimepad.
     *
     * Dus guava zelf, compileOnly: alleen bij het compileren op het pad, niet mee de app in (daar
     * zit hij al, en twee keer dezelfde klasse laat de build stukloopen). Verdwijnt guava ooit uit
     * de plugins, dan wint het echte listenablefuture:1.0 vanzelf weer en blijft dit kloppen.
     */
    compileOnly "com.google.guava:guava:33.6.0-android"
    implementation project(':capacitor-android')
    testImplementation "junit:junit:$junitVersion"
    androidTestImplementation "androidx.test.ext:junit:$androidxJunitVersion"
    androidTestImplementation "androidx.test.espresso:espresso-core:$androidxEspressoCoreVersion"
    implementation project(':capacitor-cordova-android-plugins')
}

apply from: 'capacitor.build.gradle'

try {
    def servicesJSON = file('google-services.json')
    if (servicesJSON.text) {
        apply plugin: 'com.google.gms.google-services'
    }
} catch(Exception e) {
    logger.info("google-services.json not found, google-services plugin not applied. Push Notifications won't work")
}